' MODIFY lines 305, 400, 3067

NEW

10 OUT #5B,0: DELAY0,1:OUT#5B,#A0

20 ' PC = 0 : RC = 0 Correct for current wrist alignment

30 IFHKEY<>-1THEN30

35 CLEAR1000

40 DISPLAY "SEL 1-4" : SPEAK"0M 8R 175I 0pa 2D 6S 14A 9R 8E 232F"

50 SPEAK"p lb e z 128I s eh l eh k t 168I w uh1 n pa th er u pa "

60 SAY "4"

70 SPEAK"5R " ' Set for slow speech rate

80 H=HKEY

90 ONH+2GOTO80,30,200,250,300,180,30,30,30,30,30,30,30,30,30,30,30,30,30

180 DISPLAY "Confrnc" : GOTO 500

200 DISPLAY " Lynne " : GOTO 500

250 DISPLAY " Joe " : GOTO 500

300 DISPLAY " Penny "

305 GOTO 340

310 SAY " Please give my arm room"

320 DELAY 0,2

330 HOME

340 PC = 0 : RC = 0 ' Correct for current wrist alignment

345 PITCH 180 : ROLL 0

350 GRIP 5 ,$ 'Open Gripper

360 SAY " Please give me the item"

370 SAY " Press any key when ready "

380 IF HKEY = -1 THEN 380 ' Wait until ready

390 FORCE 3,$ ' close gripper

' 400 GOTO 3067

500 DELAY 0,30

505 PRINT TIME$(2)

510 BASE 37, $

520 CCW = #F2 : CW = #C0 : GOSUB 6000

530 LFT 21,$

540 BASE 40,$

550 GOSUB 6100

580 GOSUB 9000 ' Move along bookcase

590 PRINT "Bookcase"

610 GOSUB 9100 ' John's corridor

620 PRINT "Johns corridor"

640 GOSUB 9000 ' Move along file cabinet

650 PRINT "file cabinet"

660 BASE 0,$

680 RHT 19.7, $ ' Turn for main entrance

690 PRINT "Turn for main entrance"

710 BASE 40,$

720 PRINT "40 inches"

730 GOSUB 9200 ' Follow file cabinet until it ends

740 BASE 0 : ' STOP

750 BASE 6,$ : PRINT " Past file cabinet"

790 FWUN = 30 ' Set FWUN for robot to stop 30 " before wall

795 GOSUB 6150

800 GOSUB 9300 ' Cross corridor

810 PRINT " Crossed Corridor "

820 BASE (SDIST - FDIST - CLRNCE ),$

826 PRINT " Fine Move is ", MPOS(LFT), SONAR(0) IS ", SONAR(0)

829 PRINT TIME$(2)

830 LFT 11.1 : RHT -11.1,$ ' Turn Right

840 IF H <> 3 GOTO 930

850 OUT#5B,0:DELAY0,1:OUT#5B,#A0 : DELAY 0,2 ' Stop Sonar

860 SPEAK "pa hf w eh n ah1 ie w aw z hvc er o w e n uh2 p pa pa "

870 SAY " if your boss needed a paper "

880 SAY " you brought it to her"

890 SAY " none of this e mail attachment stuff "

895 DELAY 3

900 CCW = #F2 : CW = #C0 : GOSUB 6000

930 GOSUB 9200 ' Follow left wall until it ends,

940 GOSUB 9200 ' need three, each max dist = 439.9"

945 GOSUB 9200 ' need three, each max dist = 439.9"

950 BASE 0

955 PRINT " H is " , H, "TIME IS", TIME$(2)

960 ON H+2 GOTO 1000,1000,1000,2000,3000,3000,960,960,960,960,960,960

980 GOTO 4000

1000 OUT#5B,0:DELAY0,1:OUT#5B,#A0

1002 GOSUB 6150 ' Restore variables

1010 RHT 20.4,$ 'Wide Turn Left

1020 SAY " You know "

1030 SAY " As I see it, "

1040 SAY " Humans are just self replicating robots"

1050 SAY " that came without an instruction book "

1060 SAY " or ser vis manual "

1070 DELAY 0,3 ' Wait 3 Seconds

1080 SAY " Again, "

1090 SAY " You know "

1100 SAY " As I see it, "

1110 SAY " Humans are just self replicating robots"

1120 SAY " that came without an instruction book"

1130 SAY " or ser vis manual "

1135 OUT #5B,24: DELAY0,1:OUT#5B,#BF : DELAY 0,1

1145 LFT -20.4, $ ' Back turn out of office

1150 GOSUB 9800 ' Cross in front of door

1200 GOTO 4000

2000 OUT#5B,0:DELAY0,1:OUT#5B,#A0

2002 GOSUB 6150 ' Restore variables

2010 RHT 20.4,$ 'Wide Turn Left

2020 SAY " REMEMBER, "

2030 SAY " THE ONLY REASON "

2040 SAY " a human "

2050 SAY " has A JOB"

2060 SAY " IS THAT NO ONE "

2070 SAY " HAS PRO GRAMMED A ROBOT "

2080 SAY " TO DO IT CHEAPER "

2090 DELAY 0,3 ' Wait 3 Seconds

2100 SAY " Again, "

2110 SAY " REMEMBER, "

2120 SAY " THE ONLY REASON "

2130 SAY " a human "

2140 SAY " HAs A JOB "

2150 SAY " IS THAT NO ONE "

2160 SAY " HAS PRO GRAMMED A ROBOT TO DO IT CHEAPER "

2170 GOTO 1135

3000 BASE 0

3002 GOSUB 6150 ' Restore variables

3005 OUT#5B,#0:DELAY0,1:OUT#5B,#A0 : DELAY 0,2

3010 SAY " and Joe was talking about Mac Cain and O boma "

3012 DELAY 3

3015 OUT #5B,24: DELAY0,1:OUT#5B,#BF : DELAY 0,2

3020 RHT 20.4, $ ' Turn left for A Hall

3025 BASE 25,$

3030 GOSUB 9600 ' Follow left wall until A-13

3031 GOSUB 9700 ' Follow left wall until past A-13

3032 PRINT " Past A-13 "

3033 GOSUB 9600 ' Follow left wall until D Hall

3035 BASE 0

3040 LFT 10.1,$ ' Turn 45 deg right

3050 BASE 80,$ ' Move to center of A & C Halls

3055 PRINT " H is " , H, "TIME IS", TIME$(2)

3056 IF H = 4 GOTO 5000 ' Branch for conference room

3060 ' RHT 10.1,$ ' Turn 45 deg left

3061 GRIP 5 ,$ : FORCE 1,$ : DELAY 3 'Open and close gripper

3062 LFT -20.4 : RHT 20.4,$ ' use if not into Penny's office

3063 GOTO 3550 ' use if not into Penny's office

3065 PRINT " A & D Hall diagonal completed "

3067 DELAY 0,5

3070 GOSUB 9800 ' Move until passed D Hall

3080 BASE 28,$ ' Move past wall until door

3085 PRINT " Entering Penny's office "

3090 OUT #5B,24 : DELAY0,1 : OUT#5B,#BF : DELAY 0,2

3095 LFT 22,$ ' Turn to enter office

3097 ' STOP

3098 BASE 40,$

3100 FWUN = 32 ' Set FWUN for robot to stop 32" before desk

3110 GOSUB 9300

3115 BASE 0

3120 DELAY 0,1

3125 MDIST = (SONARB - 12)

3130 OUT#5B,#0:DELAY0,1:OUT#5B,#A0 ' Stop sonar

3135 DELAY 0,2

3136 PC = 0

3140 SAY " Hi Penny, "

3150 SAY " Mark instructed me to give this to you "

3160 ARM 5 : PITCH 150,$ ' LOWER SHOULDER, Wrist up partway

3165 ELBOW 90,4, $ : PITCH 120,$ ' EXTEND ELBOW,

3180 PITCH 90,$ : ELBOW 20,$ ' Elbow to 20 deg, pitch to 90 deg

3185 ARM 0,$ : BASE MDIST, $ ' move forward for gripper over desk

3187 ' STOP

3190 GRIP 5,$ ' OPEN GRIPPER

3200 BASE -16,$ ' move backwards for gripper to clear desk

3210 ARM 5,$ : PITCH 120,$ ' Move arm away from limit switch

3220 ELBOW 152,$ ' FLEX ELBOW

3230 ARM 0 : GRIP 0,$ : PITCH 180,$ ' Wrist down

3240 SAY " Penny"

3250 SAY " did you no tice my I D badge ? "

3260 CCW = #EC : CW = #CC : GOSUB 6000 :' Set for 180 Deg

3270 PRINT "Leave Penny's Office"

3500 GOSUB 6150 ' Restore variables

3502 BASE -90,$

3503 RWUN = 70 ' Set rearward movement limit

3505 GOSUB 8900 ' BACKUP THROUGH DOOR

3507 BASE 0

3510 OUT #5B,24: DELAY0,1:OUT#5B,#BC

3515 RHT -22, $ ' Turn backwards

3520 GOSUB 9100 ' MOVE IN FRONT OF PENNY's door

3525 OUT#5B,#0:DELAY0,1:OUT#5B,#A0 ' Stop sonar

3530 BASE 20,$

3540 LFT 10,$

3550 BASE 40,$ ' Move to middle of A and D corridors

3560 LFT 40.8 : RHT -40.8 ' Twirl 360 degrees

3570 SAY " Ye aye"

3580 SAY " I went to Penny's office all by my self"

3590 DELAY 0,13 ' Make sure twirl is completed

3595 OUT #5B,24: DELAY0,1:OUT#5B,#BC

3610 BASE 60,$

3620 RHT 10,$

3640 GOSUB 9900 ' MOVE ALONG RIGHT WALL UNTIL it ends

3645 BASE 0 : OUT#5B,#0:DELAY0,1:OUT#5B,#A0

3650 LFT 20.4, $ ' TURN RIGHT

3660 SAY " AND THEN JOE TOLD ABOUT BIDEN AND PALIN "

3665 OUT #5B,24: DELAY0,1:OUT#5B,#BC

3667 BASE 24,$

3670 ' GOSUB 9400 ' MOVE ALONG RIGHT WALL UNTIL NO LEFT WALL

3680 PRINT " Back in C Hall "

4000 GOSUB 6150 ' Restore variables

4005 GOSUB 9400 ' Follow right wall until Room C-5

4010 GOSUB 9500 ' Follow right wall until past Room C-5

4020 GOSUB 9400 ' Follow right wall until Room C-8

4030 GOSUB 9500 ' Follow right wall until past Room C-8

4035 PRINT " Past C-8"

4040 GOSUB 9400 ' Follow right wall until Room C-9

4050 GOSUB 9500 ' Follow right wall until past Room C-9

4055 PRINT " Past C-9"

4060 GOSUB 9400 ' Follow right wall until Room C-11

4065 BASE 0

4070 RHT 20.4, $ ' Turn left into C-11

4080 GOSUB 9800 ' Cross corridor until at door

4090 GOSUB 9900 ' Follow right cabinets until they end

4095 BASE 0

4100 LFT 20.4 ' Turn Right

4150 BASE 24,$

4200 GOSUB 9900 ' Pass file cabinet

4210 GOSUB 9800 ' John's corridor

4220 ' GOSUB 9900 ' Pass bookcase

4230 BASE 25,$

4240 ' RHT -20.4, $

4250 ' BASE -25, $

4260 OUT#5B,0:DELAY0,1:OUT#5B,#A0 : DELAY 0,2 ' Stop Sonar

4270 SAY " Mark I am Back "

4300 END

5000 ' To Conference Room

5005 GOSUB 6150 ' Restore Variables

5010 LFT 10.1,$ ' Turn 45 deg right

5020 PRINT " A & D Hall diagonal completed "

5030 GOSUB 9100 ' Move until D Hall

5040 GOSUB 9000 ' Move until Lucy's door

5050 GOSUB 9100 ' Move past Lucy's door

5060 GOSUB 9000 ' Move Until Conference Room

5070 RHT 20.4,$ Wide Left Turn

5080 OUT#5B,0:DELAY0,1:OUT#5B,#A0

5085 BASE 24,$ ' Move into room

5087 DELAY 0,1: SAY " Penny sorry to interrupt "

5090 SAY " Mark will be a little late "

5100 SAY " He instructed me to take some notes "

5110 SAY " I will turn on the recorder now "

5115 OUT #5F,#21 : OUT #5E,#01 ' Turn on recorder

5117 GOSUB 5500 ' say time

5118 DELAY 0,1

5119 SPEAK"0M 5R 175I 0pa 2D 6S 14A 9R 8E 232F"

5120 SAY " Let me see who is here "

5130 SAY " Die Anne " : DELAY 0,1

5140 SAY " Eric " : DELAY 0,1

5150 SAY " Henrietta " : DELAY 0,1

5160 SAY " Joe " : DELAY 0,1

5170 SAY " Kathleen " : DELAY 0,1

5400 SAY " Lynne " : DELAY 0,1

5410 SAY " Sandi " : DELAY 0,1

5420 SAY " Terry " : DELAY 0,1

5430 SAY " Tracey " : DELAY 0,1

5490 END

5500 T=0: A=0:H=TIME(3):IFH<12THENA=1

5510 IFH>12THENH=H-12

5520 M=TIME(2):S=TIME(1)

5530 SPEAK"0M 9R 111I 0D pa 2D 6S 12A 8E 232F"

5540 SPEAK"thv uh1 t 136I ah1 ie 112I m i z 144I n ah1 128I w pa"

5550 X=H:GOSUB5640:IFX<>1SPEAK"136I ah 128I w er z pa":GOTO5570

5560 SPEAK"136I ah 128I w er pa"

5570 X=M:GOSUB5640:IFX<>1SPEAK"144I m i n 132I 1i t s pa":GOTO5590

5580 SPEAK"144I m i n 132I 1i t pa"

5590 SAY"and":X=S:GOSUB5640:IFX<>1SPEAK"144I s eh k 112I 1uh n d z"

5595 SPEAK " pa pa":GOTO5610

5600 SPEAK"144I s eh k 112I 1uh n d pa pa"

5610 IFA=1SPEAK"144I a ie pa":GOTO5630

5620 SPEAK"144I p e ie pa"

5630 SPEAK"96I eh1 m pa":DELAY0,1:RETURN

5640 IFX<10SAYSTR$(X):RETURN

5650 IFX=10SAY"TEN":RETURN

5660 IFX=11SAY"ILEVEN":RETURN

5670 IFX=12SAY"TWELV":RETURN

5680 IFX=13SAY"THIRTEEN":RETURN

5690 IFX=14SAY"4TEEN":RETURN

5700 IFX=15SAY"FIFTEEN":RETURN

5710 IFX=16SAY"6TEEN":RETURN

5720 IFX=17SAY"7TEEN":RETURN

5730 IFX=18SAY"ATEEN":RETURN

5740 IFX=19SAY"9TEEN":RETURN

5750 Y=INT(X/10):IFY=2THENT$="TWENTY":GOTO5790

5760 IFY=3THENT$="THIRTY":GOTO5790

5770 IFY=4THENT$="FORTY":GOTO5790

5780 IFY=5THENT$="FIFTY":GOTO5790

5790 F=X-10\*Y:IFF=0THEN5810

5800 T$=T$+STR$(F)

5810 SAYT$:RETURN

6000 OUT #5B, CW ' Set CW Sonar limit

6010 WAIT #5B,0,#FD ' Wait until sonar command processed

6020 OUT #5B, CCW ' Set CCW Sonar limit

6030 WAIT #5B,0,#FD ' Wait until sonar command processed

6040 OUT #5B,#BC ' Enable Sonars for med rate

6050 WAIT #5B,0,#FD ' Wait until sonar command processed

6060 RETURN

6100 READ FDIST, LDIST, RDIST, BKDIST, TLRNCE, CLRNCE, FARWALL, PC, RC

6110 DATA 10.5, 6.5, 10, 40, 3, 12, 90, -30, 8

6120 RETURN

6150 RESTORE

6160 READ FDIST, LDIST, RDIST, BKDIST, TLRNCE, CLRNCE, FARWALL, PC, RC

6170 RETURN

7000 ' MAIN MOVEMENT ROUTINE

7010 BASE 0 ' Stop Robot Travel

7020 BDIST = 0 ' Clear Base Distance Register

7030 NMOVE = 0 ' Clear new move flag

7040 ' Check for Obstructions

7050 IF MOVEMENT$ = "REVERSE" GOTO 7150

7060 IF SONARB < CLRNCE GOTO 7120 ' Check base sonar clearance

7070 SDIST = SONAR(0)

7090 IF SDIST < ( FDIST + CLRNCE ) GOTO 7120 ' Check upper sonar clearance

7100 IF NMOVE = 2 GOTO 7300

7110 BASE 570 : NMOVE = 2 : GOTO 7300 ' Set to move 570”, not a new move segment

7120 BDIST= BDIST + MPOS(LFT) ' Increment Distance Moved

7130 PRINT "SonarB is", SONARB, "L F R is", SONAR(270), SONAR(0), SONAR(90)

7140 BASE 0 : NMOVE = 0 : GOTO 7040 ' Clear new move flag

7150 IF SONAR(180) < ( CLRNCE + BKDIST ) GOTO 7180

7160 IF NMOVE = 2 GOTO 7300

7170 BASE -570 : NMOVE = 2 : GOTO 7300

7180 BDIST = BDIST + MPOS(LFT) ' Increment Distance Moved

7190 BASE 0 : NMOVE = 0 : GOTO 7150

7300 ' Branch on Movement End Condition

7310 ' TRACE

7320 IF MOVEUNTIL$ = "REARWALL" GOTO 7400

7330 IF MOVEUNTIL$ = "LEFTOPEN" GOTO 7500

7340 IF MOVEUNTIL$ = "LEFTWALL" GOTO 7600

7350 IF MOVEUNTIL$ = "FORWARD" GOTO 7700

7360 IF MOVEUNTIL$ = "RIGHTOPEN" GOTO 7800

7370 IF MOVEUNTIL$ = "RIGHTWALL" GOTO 7900

7380 PRINT "MISTAKE"

7390 RETURN

7400 SDIST = SONAR(180) : PRINT "REARWALL 180 distance is", SDIST

7405 IF SDIST < BKDIST GOTO 7120 ' Don't act on erroneous sonar readings

7410 IF SDIST > ( BKDIST + RWUN ) GOTO 8000

7490 RETURN

7500 SDIST = SONAR(270) : PRINT " LEFTOPEN 270 distance is", SDIST

7510 IF SDIST < LDIST GOTO 7120 ' Don't act on erroneous sonar readings

7520 LIMIT = FARWALL : IF WALL$ = "LEFT" THEN LIMIT = (2 \* CLRNCE + LDIST )

7525 IF WALL$ = "RIGHT" THEN LIMIT = (2 \* CLRNCE + RDIST )

7530 IF SDIST < LIMIT GOTO 8000

7590 RETURN

7600 SDIST = SONAR(270) : PRINT "LEFTWALL 270 distance is", SDIST

7610 IF SDIST < LDIST GOTO 7120 ' Don't act on erroneous sonar readings

7620 LIMIT = FARWALL : IF WALL$ = "LEFT" THEN LIMIT = (2 \* CLRNCE + LDIST )

7630 IF SDIST > LIMIT GOTO 8000

7690 RETURN

7700 SDIST = SONAR(0) : PRINT "FORWARD distance is", SDIST

7710 IF SDIST < FDIST GOTO 7120 ' Don't act on erroneous sonar readings

7720 IF SDIST > ( FWUN + FDIST ) GOTO 8000

7790 RETURN

7800 SDIST = SONAR(90) : PRINT "RIGHTOPEN 90 distance is", SDIST

7810 IF SDIST < RDIST GOTO 7120 ' Don't act on erroneous sonar readings

7820 LIMIT = FARWALL : IF WALL$ = "RIGHT" THEN LIMIT = (2 \* CLRNCE + RDIST )

7830 IF SDIST < LIMIT GOTO 8000

7890 RETURN

7900 SDIST = SONAR(90) : PRINT "RIGHTWALL 90 distance is", SDIST

7910 IF SDIST < RDIST GOTO 7120 ' Don't act on erroneous sonar readings

7920 LIMIT = FARWALL : IF WALL$ = "RIGHT" THEN LIMIT = (2 \* CLRNCE + RDIST )

7930 IF SDIST > LIMIT GOTO 8000

7990 RETURN

8000 IF WALLFOLLOW$ = "OFF" GOTO 7040

8010 IF WALL$ = "RIGHT" GOTO 8070

8020 SDIST = SONAR(270)

8030 SSDIST = SDIST

8035 PRINT "Left wall course correction distance is ", SDIST

8037 IF SDIST < LDIST GOTO 7120 ' Stop for erroneous data

8040 IF SDIST > (LDIST + CLRNCE + TLRNCE) GOTO 8110' Drifted right

8050 IF SDIST < (LDIST + CLRNCE - TLRNCE) GOTO 8210 ' Drifted left

8060 GOTO 7040

8070 SDIST = SONAR(90)

8075 PRINT "Right wall course correction distance is ", SDIST

8077 IF SDIST < RDIST GOTO 7120 ' Stop for erroneous data

8080 IF SDIST > (RDIST + CLRNCE + TLRNCE) GOTO 8210 ' Drifted left

8090 IF SDIST < (RDIST + CLRNCE - TLRNCE) GOTO 8110 ' Drifted right

8100 GOTO 7040

8110 BDIST = (MPOS(LFT) + MPOS(RHT))/2

8120 BASE 0

8125 ' STOP

8130 PRINT "Drifted right, distance travelled " , BDIST

8140 IF BDIST < 20 THEN TURN = 10.1 : GOTO 8160

8150 TURN = 10.1 + (ATN (TLRNCE/BDIST) \*13.24)

8160 RHT TURN,$ ' Turn left to correct drift

8165 PRINT " Turn = ", TURN

8170 BASE (TLRNCE ),$ ' Move Tolerance distance

8180 LFT 10.1,$ ' Turn to head straight

8190 BASE 0

8195 ' STOP

8200 GOTO 7020

8210 BDIST = (MPOS(LFT) + MPOS(RHT))/2

8220 BASE 0

8225 ' STOP

8230 PRINT "Drifted left, distance travelled " , BDIST

8240 IF BDIST < 20 THEN TURN = 10.1 : GOTO 8260

8250 TURN = 10.1 + (ATN (TLRNCE/BDIST) \*13.24)

8260 LFT TURN,$ ' Turn right to correct drift

8265 PRINT " Turn = ", TURN

8270 BASE (TLRNCE ),$ ' Move Tolerance distance

8280 RHT 10.1,$ ' Turn to head straight

8290 BASE 0

8295 ' STOP

8300 GOTO 7020

8900 PRINT " Rearward until wall"

8920 MOVEUNTIL$ = "REARWALL"

8930 WALLFOLLOW$ = "OFF"

8940 WALL$ = "LEFT"

8950 MOVEMENT$ = "REVERSE"

8960 ' CCW = #DC : CW = #CC

8970 GOTO 7000

8980 RESTORE ' Restore CLRNCE

8990 RETURN

9000 PRINT " Move along left wall until end"

9010 MOVEUNTIL$ = "LEFTOPEN"

9020 WALLFOLLOW$ = "OFF"

9030 WALL$ = "LEFT"

9040 MOVEMENT$ = "FORWARD"

9050 ' CCW = #F2 : CW = #C0

9060 GOTO 7000

9070 RETURN

9100 PRINT "Move until Left Wall "

9110 MOVEUNTIL$ = "LEFTWALL"

9120 WALLFOLLOW$ = "OFF"

9130 WALL$ = "LEFT"

9140 MOVEMENT$ = "FORWARD"

9150 ' CCW = #F2 : CW = #C0

9160 GOTO 7000

9170 RETURN

9200 PRINT " Follow left wall until ends with course correction"

9210 MOVEUNTIL$ = "LEFTOPEN"

9220 WALLFOLLOW$ = "ON"

9230 WALL$ = "LEFT"

9240 MOVEMENT$ = "FORWARD"

9250 ' CCW = #F2 : CW = #C0

9260 GOTO 7000

9270 RETURN

9300 PRINT "Cross open space until FDIST away from wall"

9310 MOVEUNTIL$ = "FORWARD"

9320 WALLFOLLOW$ = "OFF"

9330 WALL$ = "LEFT"

9340 MOVEMENT$ = "FORWARD"

9350 ' CCW = #D0 : CW = #C0

9360 GOTO 7000

9370 RETURN

9400 PRINT " Move along right wall until no left wall"

9410 MOVEUNTIL$ = "LEFTOPEN"

9420 WALLFOLLOW$ = "ON"

9430 WALL$ = "RIGHT"

9440 MOVEMENT$ = "FORWARD"

9450 GOTO 7000

9460 ' CCW = #F2 : CW = #C6

9470 RETURN

9500 PRINT " Move along right wall until left wall"

9510 MOVEUNTIL$ = "LEFTWALL"

9520 WALLFOLLOW$ = "ON"

9530 WALL$ = "RIGHT"

9540 MOVEMENT$ = "FORWARD"

9550 ' CCW = #F2 : CW = #C6

9560 GOTO 7000

9570 RETURN

9600 PRINT " L wall until no R wall "

9610 MOVEUNTIL$ = "RIGHTOPEN"

9620 WALLFOLLOW$ = "ON"

9630 WALL$ = "LEFT"

9640 MOVEMENT$ = "FORWARD"

9650 ' CCW = #F2 : CW = #C6

9660 GOTO 7000

9670 RETURN

9700 PRINT "L wall until R wall "

9710 MOVEUNTIL$ = "RIGHTWALL"

9720 WALLFOLLOW$ = "ON"

9730 WALL$ = "LEFT"

9740 MOVEMENT$ = "FORWARD"

9750 ' CCW = #F2 : CW = #C6

9760 GOTO 7000

9770 RETURN

9800 PRINT "Right Open Space Until Right Wall"

9810 MOVEUNTIL$ = "RIGHTWALL"

9820 WALLFOLLOW$ = "OFF"

9830 WALL$ = "RIGHT"

9840 MOVEMENT$ = "FORWARD"

9850 ' CCW = #D0 : CW = #C6

9860 GOTO 7000

9870 RETURN

9900 PRINT " R wall until it ends "

9910 MOVEUNTIL$ = "RIGHTOPEN"

9920 WALLFOLLOW$ = "ON"

9930 WALL$ = "RIGHT"

9940 MOVEMENT$ = "FORWARD"

9950 ' CCW = #D0 : CW = #C6

9960 GOTO 7000

9970 RETURN